GTL/src/slot_map.zig

//! ----------------------------------------------------
//! ----------------------------------------------------

const std = @import("std");
const Handle = @import("handle.zig").Handle;

/// ----------------------------------------------------
/// # Example
///
/// ```zig
/// // --- MATERIALS ---
/// var materials: SlotMap(Material) = .init(alloc);
/// defer materials.deinit();
///
/// // --- ADD MATERIALS ---
/// _ = try materials.put(.{ .style = .{ .albedo = .{ 0.8, 0.2, 0.2, 1.0 } } });
/// _ = try materials.put(.{ .unique = .{ .topology = .line_list } });
/// ```
/// ----------------------------------------------------
pub fn SlotMap(comptime T: type) type {
    return struct {
        const Self = @This();

        //
        // FIELDS
        //

        // --- VALUES ---
        values: std.ArrayList(T),

        // --- LIFE TIMES ---
        generations: std.ArrayList(u32),
        free_list: std.ArrayList(u32),

        // --- MEMORY ---
        alloc: std.mem.Allocator,

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn init(alloc: std.mem.Allocator) Self {
            return .{
                .values = .empty,

                .generations = .empty,
                .free_list = .empty,

                .alloc = alloc,
            };
        }

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn deinit(self: *Self) void {
            self.values.deinit(self.alloc);
            self.generations.deinit(self.alloc);
            self.free_list.deinit(self.alloc);
        }

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn put(
            self: *Self,
            value: T,
        ) error{OutOfMemory}!Handle(T) {
            // --- NEW GENERATION ---
            if (self.free_list.pop()) |idx| {
                self.values.items[@intCast(idx)] = value;
                self.generations.items[@intCast(idx)] += 1;

                return .{
                    .idx = idx,
                    .gen = self.generations.items[idx],
                };
            }

            // --- METADATA ---
            const idx = self.values.items.len;
            const handle: Handle(T) = .{
                .idx = @intCast(idx),
                .gen = 1,
            };

            // --- NEW VALUE ---
            try self.values.append(self.alloc, value);
            errdefer _ = self.values.swapRemove(idx);

            // --- NEW GENERATION ---
            try self.generations.append(self.alloc, 1);

            // --- RESULT ---
            return handle;
        }

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn remove(
            self: *Self,
            handle: Handle(T),
        ) void {
            const idx: u32 = handle.idx;

            // --- CHECK IF STALE ---
            if (idx >= self.generations.items.len) return;
            if (self.generations.items[idx] != handle.gen) return;

            // --- GENERATION ---
            self.generations.items[idx] +|= 1;
            self.free_list.append(self.alloc, idx) catch |err| {
                std.debug.print("[SLOTMAP_ERROR] {s}\n", .{@errorName(err)});
            };
        }

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn get(self: *Self, handle: Handle(T)) ?*T {
            if (handle.idx >= self.values.items.len) return null;
            if (self.generations.items[handle.idx] != handle.gen) return null;
            return &self.values.items[handle.idx];
        }

        /// ----------------------------------------------------
        /// ----------------------------------------------------
        pub fn items(self: *Self) []T {
            return self.values.items;
        }
    };
}